Codice:

set note1=Linea=1280/384 mcr=64

Codice:

set publicip_netmask=248

Codice:

@echo off

rem Versione derivata dalla 0.4.2 di r3lative

rem *******************
rem ***** parametri *****
rem *******************

rem *** Versione del programma
set verp=Version 1.0 by sun83

rem *** Imposta l'editor da usare per visualizzare
rem *** se vuota, usa l'editor predefinito di windows
rem set editor=%SystemRoot%\system32\notepad.exe
set editor="C:\Programmi\Windows NT\Accessori\wordpad.exe"

rem *** file temporaneo
set tfn=%temp%\e4a.tmp

rem *** file di testo contenente i risultati, è il file da aprire se volete rivedere i risultati
set fn=%temp%\e4a.txt

rem *** file parametri da passare a sed.
set sed=%temp%\e4a.sed

rem *** sito di riferimento per i test di ping e di tracert
set sito=maya.ngi.it

rem *** numero di ping da eseguire, è caldamente consigliati di non modificarlo.
rem *** nel caso, bisogna modificare anche la riga "echo 13,106d > %sed%"
rem *** questo comando indica a sed di cancellare le righe dalla 13 alla 106,
rem *** quindi se si modifica il n° di ping bisogna anche modificare questi valori.
rem *** (di norma il 106, basta fare la stessa modifica che avete fatto al n° di ping, tipo -50 o +100)
set pingn=50
set pingdelfromrow=6
set pingdeltorow=59
set pingdelrow=67


rem *** se ftpwget=1 usa il wget, se ftpwget=0 usa ftp di windows
set ftpwget=1

rem *** file parametri per l'FTP
set ftp=%temp%\e4a.ftp

rem *** file di log per l'FTP
set ftplog=%temp%\e4a.ftp.log

rem *** sito da cui fare le prove FTP di download
set ftpsite=debian.fastweb.it

rem *** nome del file remoto da scaricare (path assoluti)
set ftpfile=/debian/ls-lR.gz

rem *** nome del file locale scaricato (path assoluti)
set ftplocalfile=%temp%\ls-lr.gz.tmp

rem *** file di destinazione per l'FTP
set ftpdestfile=e4a.ftp.file



rem *** file parametri per l'HTTP
set http=%temp%\e4a.http

rem *** file di destinazione per l'HTTP
set httpdestfile=e4a.http.file

rem *** file http da scaricare
set httpdownload=http://debian.fastweb.it/debian/ls-lR.gz


rem *** variabile ambiente per impostare correttamente il code, senza dover fare nulla sullo script
set varcode=code


rem *** publicip_cache se è impostato a 1, memorizza in temp l'ip pubblico
set publicip_temp=%temp%\mypublicip.txt

rem *** netmask ip pubblici assegnati
set publicip_netmask=248


rem *** Note che possono essere aggiunte in coda al file con i risultati
rem *** si tratta di 3 righe che possono essere inserite, se non usate,
rem *** non vengono inserite nel risultato (ovvero non vengono lasciate riche vuote)
rem set note1=Linea:1536/512 MCR:128
rem set note2=
rem set note3=
set note1=Linea=1280/384 mcr=64
set note2=
set note3=


rem ***************************
rem *** INIZIO PROGRAMMA ***
rem ***************************

echo Test E4A in esecuzione
echo %verp%
echo Attendere prego ...

echo [%varcode%]Test E4A %verp%> %tfn%
echo Data: %date% %time% >> %tfn%

echo Ping in corso ...
rem echo. >>%tfn%
echo ************************************************* >> %tfn%
echo Ping verso %sito%: >> %tfn%
ping %sito% -n %pingn% >> %tfn%
echo ************************************************* >> %tfn%

echo Tracert in corso ...
tracert %sito% >> %tfn%
echo ************************************************* >> %tfn%

echo Test HTTP in corso ...
wget %httpdownload% --output-document=%httpdestfile% --output-file=%http%
sed -n /KB\/s)/p %http% >> %tfn%
del %httpdestfile%

IF %ftpwget%==1 goto ftpw

echo Test FTP in corso ...
echo open %ftpsite%         >  %ftp%
echo user anonymous         >> %ftp%
echo pippo@pippo.it         >> %ftp%
echo.               >> %ftp%
echo cd /            >> %ftp%
echo lcd %temp%            >> %ftp%
echo binary            >> %ftp%
echo get %ftpfile% %ftplocalfile%   >> %ftp%
echo bye             >> %ftp%

ftp -n -s:%ftp% > %ftplog%
echo FTP download filename %ftpfile% from %ftpsite% >> %tfn%
sed -n /byte\/sec/p %ftplog% >> %tfn%

goto noftpw

:ftpw
echo Test FTP in corso ...
wget ftp://%ftpsite%%ftpfile% --output-document=%ftpdestfile% --output-file=%ftplog%
sed -n /KB\/s)/p %ftplog% >> %tfn%
del %ftpdestfile%

:noftpw

echo ************************************************* >> %tfn%

echo Rilevazione completata

rem *** cancella le doppie righe vuote dal file
echo s/.$//g    > %sed%

rem *** cancello le righe del ping che non interessano
echo %pingdelfromrow%,%pingdeltorow%d    >> %sed%
echo %pingdelrow%d          >> %sed%

rem *** sostituisco la parte finale dei test di velocità
sed -r -e "s/- `%httpdestfile%' saved \[[0-9\/]*\]/@ HTTP /g" %tfn% > %fn%
sed -r -e "s/- `%ftpdestfile%' saved \[[0-9]*\]/@ FTP /g" %fn% > %tfn%

rem *** sostituisco gli indirizzi privati e pubblici con testi non significativi
rem wget http://sun83.altervista.org/tools/e4a/sedip.php?netmask=255.255.255.%publicip_netmask% -q -O %publicip_temp%
wget http://sun83.netsons.org/tools/e4a/sedip.php?netmask=255.255.255.%publicip_netmask% -q -O %publicip_temp%

sed -f %publicip_temp% %tfn% > %fn%
sed -r -e "s/([A-Za-z0-9\.]+ +[([])?(10\.[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3}|172\.1[6-9]\.[0-9]{1,3}\.[0-9]{1,3}|172\.2[0-9]\.[0-9]{1,3}\.[0-9]{1,3}|172\.3[0-1]\.[0-9]{1,3}\.[0-9]{1,3}|192\.168\.[0-9]{1,3}\.[0-9]{1,3}|127\.0\.0\.1)[])]?/xxx.xxx.xxx.xxx/g" %fn% > %tfn%

rem *** eseguo il sed
sed -f %sed% %tfn% > %fn%

rem *** Aggiungo testi vari che voglio vengano inseriti
if "%note1%*" == "*"  goto noNote1
echo %note1% >> %fn%
:noNote1
if "%note2%*" == "*"  goto noNote2
echo %note2% >> %fn%
:noNote2
if "%note3%*" == "*"  goto noNote3
echo %note3% >> %fn%
:noNote3

echo *************************************************[/%varcode%] >> %fn%

:fine
echo Visualizzo i risultati

%editor% %fn%