Codice:

@echo off

set path=%ProgramFiles%\GnuWin32\bin;%path%

rem *******************
rem ***** parametri *****
rem *******************

rem *** Versione del programma
set verp=versione 0.4.2 by r3lative

rem *** Imposta l'editor da usare per visualizzare
rem *** se vuota, usa l'editor predefinito di windows
rem set editor=%SystemRoot%\system32\notepad.exe
set editor="C:\Windows\notepad.exe"

rem *** file temporaneo
set tfn=%temp%\e4a.tmp

rem *** file di testo contenente i risultati, è il file da aprire se volete rivedere i risultati
set fn=%temp%\e4a.txt

rem *** file parametri da passare a sed.
set sed=%temp%\e4a.sed

rem *** sito di riferimento per i test di ping e di tracert
set sito=maya.ngi.it

rem *** numero di ping da eseguire, è caldamente consigliati di non modificarlo.
rem *** nel caso, bisogna modificare anche la riga "echo 13,106d > %sed%"
rem *** questo comando indica a sed di cancellare le righe dalla 13 alla 106,
rem *** quindi se si modifica il n° di ping bisogna anche modificare questi valori.
rem *** (di norma il 106, basta fare la stessa modifica che avete fatto al n° di ping, tipo -50 o +100)
set pingn=10

rem *** file parametri per l'FTP
set ftp=%temp%\e4a.ftp

rem *** file di log per l'FTP
set ftplog=%temp%\e4a.ftp.log

rem *** sito da cui fare le prove FTP di download
set ftpsite=debian.fastweb.it

rem *** nome del file remoto da scaricare (path assoluti)
set ftpfile=/debian/ls-lR.gz

rem *** nome del file locale scaricato (path assoluti)
set ftplocalfile=%temp%\ls-lr.gz.tmp

rem *** variabile ambiente per impostare correttamente il code, senza dover fare nulla sullo script
set varcode=code

rem *** se avete un firewall, tra la vostra rete, e internet.
rem *** per mascherare i dati del vs firewall, bisogna inserire la stringa che lo identifica,
rem *** ovvero fate un tracert, e vedete la prima riga, di solito compare il nome del firewall,
rem *** e tra parentesi quadre l'indirizzo IP. sostituite le scritte comprensive degli spazi
rem *** sul parametro repa, facendo attenzione che per indicare le parentesi quadre dovete usare
rem *** i simboli \[ e \].
set repa=firewall \[192.168.1.1\]

rem *** per mascherare il vostro indirizzo pubblico, inseritelo nel parametro,
rem *** il programma provvede automaticamente a sostituirlo con "myPublicIP".
set repb=set repb=host444.pool-88.213.174.vicenzawireless.com \[88.213.174.25\]

rem *** Note che possono essere aggiunte in coda al file con i risultati
rem *** si tratta di 3 righe che possono essere inserite, se non usate,
rem *** non vengono inserite nel risultato (ovvero non vengono lasciate riche vuote)
rem set note1=Linea=1280/384 mcr=64
rem set note2=
rem set note3=
set note1=Linea: Segreta :))
set note2=
set note3=

rem ***************************
rem *** INIZIO PROGRAMMA ***
rem ***************************

echo test E4A in esecuzione
echo %verp%
echo attendere prego ...

echo [%varcode%]Test E4A %verp%> %tfn%
echo Sito : %sito% >> %tfn%
echo Data : %date% %time% >> %tfn%

echo Ping in corso ...
rem echo. >>%tfn%
echo ************************************************* >> %tfn%

ping %sito% -n %pingn% >> %tfn%
echo ************************************************* >> %tfn%

echo Tracert in corso ...
tracert -d %sito% >> %tfn%
echo ************************************************* >> %tfn%

echo FTP in corso ...
echo open %ftpsite% > %ftp%
echo user anonymous >> %ftp%
echo pippo@pippo.it >> %ftp%
echo. >> %ftp%
echo cd / >> %ftp%
echo lcd %temp% >> %ftp%
echo binary >> %ftp%
echo get %ftpfile% %ftplocalfile% >> %ftp%
echo bye >> %ftp%

ftp -n -s:%ftp% > %ftplog%
echo FTP download filename %ftpfile% from %ftpsite% >> %tfn%
sed -n /byte\/sec/p %ftplog% >> %tfn%
echo *************************************************[/%varcode%] >> %tfn%

echo Rilevazione completata

rem *** cancella le doppie righe vuote dal file
echo s/\r//g > %sed%
echo s/$/\r/g >> %sed%
rem *** cancello le righe del ping che non interessano
echo 6,19d >> %sed%
echo 117d >> %sed%
rem *** sostituisco gli indirizzi privato con testi non significativi
echo s/%repa%/myFirewall/g >> %sed%
echo s/%repb%/myPublicIP/g >> %sed%

rem *** eseguo il sed
sed -f %sed% %tfn% > %fn%

rem *** Aggiungo testi vari che voglio vengano inseriti
if "%note1%*" == "*" goto noNote1
echo %note1% >> %fn%
:noNote1
if "%note2%*" == "*" goto noNote2
echo %note2% >> %fn%
:noNote2
if "%note3%*" == "*" goto noNote3
echo %note3% >> %fn%
:noNote3

:fine
echo Visualizzo i risultati

%editor% %fn%

Codice:

Test E4A versione 0.4.2 by r3lative
Sito : maya.ngi.it
Data : 26/11/2007 8.02.32,75
*************************************************

Pacchetti: Trasmessi = 10, Ricevuti = 10,
Persi = 0 (0% persi),
Tempo approssimativo percorsi andata/ritorno in millisecondi:
Minimo = 16ms, Massimo = 28ms, Medio = 21ms
*************************************************

Traccia instradamento verso maya.ngi.it [88.149.128.3]
su un massimo di 30 punti di passaggio:

1 <1 ms <1 ms <1 ms 88.213.174.25
2 2 ms 2 ms 2 ms 77.42.35.210
3 7 ms 8 ms 5 ms 88.213.136.185
4 13 ms 10 ms 11 ms 88.213.136.189
5 18 ms 12 ms 25 ms 77.42.48.201
6 15 ms 20 ms 16 ms 194.177.69.1
7 12 ms 21 ms 27 ms 217.19.158.1
8 211 ms 44 ms 23 ms 217.19.145.1
9 20 ms 23 ms 18 ms 217.19.144.166
10 17 ms 15 ms 16 ms 217.29.66.2
11 24 ms 22 ms 19 ms 212.239.97.113
12 21 ms 18 ms 36 ms 212.239.110.46
13 37 ms 23 ms 21 ms 81.174.0.246
14 23 ms 18 ms 20 ms 88.149.128.3

Traccia completata.
*************************************************
FTP download filename /debian/ls-lR.gz from debian.fastweb.it
*************************************************